DISPLAY
    Simulation of heat transfer to and from the solid
    material surrounding a tunnel, when a moving heat
    source (eg a train) passes along it. Air also flows
    along the tunnel.
  ENDDIS
 
    GXNEPA is employed for this case.
 
    The locally-defined variables are as follows:
 
     H1IN   = inlet enthalpy of air             J/kg
     H1INIT = initial enthalpy of solid         J/kg
     FLO1   = mass-flow rate of air             kg/s
     TIME   = transit time of train             s
     INTVLS = number of time intervals
     SPECHT = specific heat of solid            J/kg.deg
     SPEAIR = specific heat of air              J/kg.deg
     COND   = thermal conductivity of solid     J/m.deg
     DENSTY = density of the solid              kg/m**3
     DENAIR = density of air                    kg/m**3
     VELAIR = air velocity                      m/s
 
REAL(H1IN,H1INIT,FLO1,TIME,DENSTY,COND,SPECHT,HEATSO)
REAL(DENAIR,SPEAIR,VELAIR)
INTEGER(INTVLS)
 
SPECHT=880.0;  HEATSO =1.0E6;   TIME  =200.0; INTVLS=20
DENSTY=1460.0; COND   =1.3;     DENAIR=1.0;   SPEAIR=1.E3
VELAIR=5.0;    H1IN   =0.0;     H1INIT=0.0
FLO1  =VELAIR*DENAIR*SPEAIR/SPECHT
 
    GROUP 1. Run title
TEXT(Transient Tunnel Heat Transfer   
TITLE
 
    GROUP 2. Transience; time-step specification
STEADY=F; TLAST=1.0; LSTEP=INTVLS
TFRAC(1)=-LSTEP/2; TFRAC(2)=2.0*TIME/LSTEP
TFRAC(3)=LSTEP/2;  TFRAC(4)=TFRAC(2)*10.0
 
   GROUP 3. X-direction grid specification
CARTES=F;GRDPWR(X,1,2.0*3.14159,1.0)
 
    GROUP 4. Y-direction grid specification
NY=10;YVLAST=1.0
  **The tunnel has a radius of 5 m; and the surrounding
    solid is subdivided into cylindrical layers 0.015m
    thick.
YFRAC(1)=-1.0;YFRAC(2)=5.0;YFRAC(3)=9.0;YFRAC(4)=0.015
 
    GROUP 5. Z-direction grid specification
  **The tunnel is 1 km long
GRDPWR(Z,10,1.E3,1.0)
 
    GROUP 7. Variables stored, solved & named
SOLVE(H1);STORE(NPOR,VPOR)
 
    GROUP 8. Terms (in differential equations) & devices
  **The built-in source and convection terms are cut out,
    convection being handled by the NEL1 source below.
TERMS(H1,N,N,Y,Y,Y,Y)
 
    GROUP 9. Properties of the medium (or media)
RHO1=DENSTY;PRNDTL(H1)=ENUL*DENSTY*SPECHT/COND
 
    GROUP 11. Initialization of variable or porosity fields
INIADD=F
FIINIT(H1)=H1INIT;FIINIT(NPOR)=1.0;FIINIT(VPOR)=1.0
PATCH(TUNNEL,INIVAL,1,1,1,1,1,NZ,1,1)
  **The north porosity is set so as to express the fact
    that heat travels into the first solid layer from
    its inner surface, not from the the point within the
    air cell which PHOENICS assumes.
INIT(TUNNEL,NPOR,0.0,(YFRAC(2)+YFRAC(4))/YFRAC(4))
  **The volume porosity is set to the ratio below, so
    that the transient terms are correctly computed.
INIT(TUNNEL,VPOR,0.0,SPEAIR*DENAIR/(SPECHT*DENSTY))
 
    GROUP 13. Boundary conditions and special sources
  **Low boundary; fluid inlet ;
PATCH(INLEH1,LOW,1,1,1,1,1,1,1,LSTEP)
COVAL(INLEH1,H1,FLO1,H1IN)
  **Flow of fluid along IY=1
PATCH(NEL1,LOW,1,1,1,1,2,NZ,1,LSTEP)
COVAL(NEL1,H1,FLO1,LOCNE)
  **Heat source which moves from one cell to the next
    in each time step, ie at speed ZWLAST/TIME,
    which equals 18 km/h in this case.
 
DO II=1,10
+ PATCH(HEATR:II:,CELL,1,1,1,1,II,II,II,II)
+ COVAL(HEATR:II:,H1,FIXFLU,HEATSO)
ENDDO
 
    GROUP 15. Termination of sweeps
RESREF(H1)=1.E-6*HEATSO
LSWEEP=2
SPEDAT(SET,GXMONI,TRANSIENT,L,F) 
    GROUP 21. Print-out of variables
OUTPUT(H1,Y,Y,Y,Y,Y,Y)
OUTPUT(NPOR,N,N,N,N,N,N)
OUTPUT(VPOR,N,N,N,N,N,N)
 
    GROUP 22. Spot-value print-out
IZMON=NZ/2;TSTSWP=1;ITABL=2
 
    GROUP 23. Field print-out and plot control
NZPRIN=NZ/5;IZPRL=NZ-1;IPLTL=LSWEEP;NPLT=1
NTPRIN=1
 
PATCH(LONGPLOT,PROFIL,1,1,2,2,1,NZ,1,LSTEP)
PLOT(LONGPLOT,H1,0.0,0.0)
 
PATCH(MAP,CONTUR,1,1,2,NY,1,NZ,1,LSTEP)
PLOT(MAP,H1,0.0,10.0)
 
PATCH(TIMEPLOT,PROFIL,1,1,2,2,NZ/2,NZ/2,1,LSTEP)
PLOT(TIMEPLOT,H1,0.0,0.0)