TEXT(YX BFC DIAGONAL SCALAR CONVECTION
TITLE
  DISPLAY
  This problem concerns the pure convection of a step profile of
  a scalar by a unidirectional and uniform flow field, which forms
  an angle 22.5 degrees with the horizontal axis. The case is
  identical to N101 except that the simulation is performed on a
  skewed box which is inclined at 45 degrees to the horizontal.
  The grid employed is 20 by 20 and three scalars are solved, each
  of which differs according the selected scheme. The case provides
  a basic test of the higher-order schemes on non-orthogonal meshes.
  ENDDIS
  PHOTON USE
    P
 
 
 
     0.20443E+04 0.15633E+04 CR
  gr z 1;vec z 1 sh
  msg Velocity vectors & mesh
  msg press  to continue
  pause
  cl;gr ou z 1;con USOL z 1 fi;.01
  msg Upwind Differencing Scheme
  msg press  to continue
  pause
  cl;con QSOL z 1 fi;.01
  msg QUICK Scheme
  msg press  to continue
  pause
  cl;con BSOL z 1 fi;.01
  msg Superbee Scheme
  msg press  to end
  pause
  ENDUSE
   GROUP 1.  Run identifiers and other preliminaries.
TEXT(YX BFC DIAGONAL SCALAR CONVECTION
REAL(VTOT,FLANG,PI,XLEN,DTF,SINANG,COSANG,UCRTX,VCRTY)
PI=3.1415927;VTOT=1.0;FLANG=22.5*PI/180.;SINANG=SIN(FLANG)
XLEN=1.0;COSANG=COS(FLANG);UCRTX=VTOT*COSANG;VCRTY=VTOT*SINANG
   GROUP 6.  Body-fitting and other grid distortions.
BFC=T
GSET(P,P01,0.0000,0.0000,0.0000)
GSET(P,P02,1.0000,0.0000,0.0000)
GSET(P,P03,1.0000,1.0000,0.0000)
GSET(P,P04,0.0000,1.0000,0.0000)
GSET(L,L01,P01,P02,20,1.0)
GSET(L,L02,P02,P03,20,1.0)
GSET(L,L03,P03,P04,20,1.0)
GSET(L,L04,P04,P01,20,1.0)
GSET(F,F01,P01,-,P02,-,P03,-,P04,-)
GSET(D,20,20,1,1.0000,1.0000,0.1000)
GSET(M,F01,+I+J,1,1,1,TRANS)
GSET(P,P01,0.0000,0.0000,0.0000)
GSET(P,P02,1.0000,0.0000,0.0000)
GSET(P,P03,1.7071,0.7071,0.0000)
GSET(P,P04,0.7071,0.7071,0.0000)
GSET(L,L01,P01,P02,20,1.0)
GSET(L,L02,P02,P03,20,1.0)
GSET(L,L03,P03,P04,20,1.0)
GSET(L,L04,P04,P01,20,1.0)
GSET(F,F01,P01,-,P02,-,P03,-,P04,-)
GSET(D,20,20,1,1.0000,1.0000,0.1000)
GSET(M,F01,+I+J,1,1,1,TRANS)
GSET(C,K2,F,K1,1,20,1,20,+,0,0,1.0000E-02)
GSET(C,K:NZ+1:,F,K1,1,NX,1,NY,+,0.0,0.0,0.1,INC,1.0)
NONORT=T;STORE(UCRT,VCRT,WCRT)
   GROUP 7.  Variables named,stored & solved.
SOLVE(P1,U1,V1);SOLUTN(P1,Y,Y,Y,N,N,N)
SOLVE(C1);NAME(C1)=USOL;SOLVE(C2);NAME(C2)=QSOL
SOLVE(C3);NAME(C3)=BSOL
SOLUTN(USOL,P,P,P,P,P,N);SOLUTN(QSOL,P,P,P,P,P,N)
SOLUTN(BSOL,P,P,P,P,P,N)
   GROUP 8.  Terms (in differential equations) and devices.
SCHEME(MINMOD,U1,V1);SCHEME(QUICK,QSOL);SCHEME(SUPBEE,BSOL)
   GROUP 9.  Properties of the medium (or media).
RHO1=1.161;ENUL=1.5890E-05;ENUT=0
   GROUP 11. Initialization of fields of variables
   ** ei=(1,0,0) ej=(.7071,.7071,0.) q=(ucrtx,vcrty,0.)
FIINIT(U1)=UCRTX;FIINIT(V1)=.7071*UCRTX+.7071*VCRTY
FIINIT(UCRT)=UCRTX;FIINIT(VCRT)=VCRTY
   GROUP 12. Convection and diffusion adjustments
   GROUP 13. Boundary conditions and special sources
   * INLET boundary condition, name INB
INLET(BFCINB,SOUTH,#1,#1,#1,#1,#1,#1,#1,#NREGT)
VALUE(BFCINB,U1,GRND1);VALUE(BFCINB,UCRT,UCRTX)
VALUE(BFCINB,V1,GRND1);VALUE(BFCINB,VCRT,VCRTY)
VALUE(BFCINB,P1,GRND1);VALUE(BFCINB,USOL,1)
VALUE(BFCINB,QSOL,1);VALUE(BFCINB,BSOL,1);BFCA=RHO1
   * INLET boundary condition, name INS
INLET(BFCINS,WEST,#1,#1,#1,#1,#1,#1,#1,#NREGT)
VALUE(BFCINS,U1,GRND1);VALUE(BFCINS,UCRT,UCRTX)
VALUE(BFCINS,V1,GRND1);VALUE(BFCINS,VCRT,VCRTY)
VALUE(BFCINS,P1,GRND1);VALUE(BFCINS,USOL,0)
VALUE(BFCINS,QSOL,0);VALUE(BFCINS,BSOL,0)
   * OUTLET boundary condition, name OUTT
OUTLET(OUTT,NORTH,#1,#1,#1,#1,#1,#1,#1,#NREGT)
VALUE(OUTT,U1,SAME);VALUE(OUTT,V1,SAME)
VALUE(OUTT,P1,0);VALUE(OUTT,USOL,SAME)
VALUE(OUTT,QSOL,SAME);VALUE(OUTT,BSOL,SAME)
   * OUTLET boundary condition, name OUTS
OUTLET(OUTS,EAST,#1,#1,#1,#1,#1,#1,#1,#NREGT)
VALUE(OUTS,U1,SAME);VALUE(OUTS,V1,SAME)
VALUE(OUTS,P1,0);VALUE(OUTS,USOL,SAME)
VALUE(OUTT,QSOL,SAME);VALUE(OUTT,BSOL,SAME)
   GROUP 15. Termination criteria for sweeps & iterations
LSWEEP=1000
   GROUP 16. Termination criteria for inner iterations.
   GROUP 17. Under-relaxation and related devices.
DTF=XLEN/VTOT
RELAX(P1,LINRLX,0.5);RELAX(U1,FALSDT,DTF);RELAX(V1,FALSDT,DTF)
RELAX(USOL,FALSDT,DTF);RELAX(QSOL,FALSDT,DTF)
RELAX(BSOL,FALSDT,0.1*DTF)
   GROUP 18. Limits on variables values.
   GROUP 19. Data communicated by SATELLITE to GROUND
   GROUP 20. Control of preliminary printout
   GROUP 21. Frequency and extent of field printout.
   GROUP 22. Location of spot-values
IXMON=11;IYMON=11;TSTSWP=-1
   GROUP 23. Variable-by-variable field printout
ITABL=3;NPLT=1
   GROUP 24. Preparation for continuation runs.