GROUP 1. Run title and other preliminaries
  DISPLAY
  The flow considered is a plane or round submerged jet of fluid
  discharging into a stagnant environment of another fluid. The jet
  is isothermal and buoyancy effects are negligible. The turbulence
  is simulated with the Reynolds-stress transport model ( RSTM ),
  which may be one of three variants, namely: the IPM pressure-
  strain model (IRSMHM=0); the model coefficients of Gibson &
  Younis plus IPM (IRSMHM=1); the QIM pressure-strain model
  (IRSMHM=2). Modelled tranpsort equations are solved for the
  turbulent scalar fluxes of the injected fluid.
  ENDDIS
 
  The calculations are started at the jet discharge, and the
  parabolic marching integration is carried out until both the mean
  flow and turbulence profiles become self similar. Thirty lateral/
  radial grid cells are employed across the jet, together with a
  forward step size of about 1% (DZW1) of the local jet width/
  radius. The y-extent of the grid increases linearly with
  downstream distance so as to accommodate the spread of the jet.
  For the plane jet, the calculation is terminated about 90 slot
  widths from the jet discharge. For the round jet, it is
  terminated at about 70 diameters from the source.
 
  The main results of the calculations are compared with those of
  experiment in the table below.
 
    plane jet          IPM     IPM/GY     QIM     Data
 
    dyw/dz            .101      .093     .117     .110
    dyt/dz            .132      .120     .152     .140
    vw,max/wm**2      .021      .020     .025     .024
    vc,max/(wm*cm)    .027      .024     .031     .032
 
    round jet          IPM     IPM/GY     QIM     Data
 
    dyw/dz            .120      .103     .145     .086
    dyt/dz            .160      .145     .191     .110
    vw,max/wm**2      .023      .020     .030     .019
    vc,max/(wm*cm)    .028      .025     .036     .016
 
  The table indicates the values of the half-width spreading rates
  of the velocity and scalar-concentration fields, and the maximum
  values of the normalised values of the cross-stream turbulent
  shearing stress and scalar-concentration flux. No grid
  sensitivity studies have been performed, but these results are
  in close agreement with those reported in the literature.
 
CHAR(FLOTYP);IRSMSM=2;IRSMHM=0;CARTES=T
IF(CARTES) THEN
+ FLOTYP=PLANE
ELSE
+ FLOTYP=ROUND
ENDIF
 
TEXT(RSTM_2D PARABOLIC :FLOTYP: JET        :T603
TITLE
  ** Jet-Discharge values
REAL(REYNO,CJET,WJET,TKEIN,EPSIN,HSLOT,GMIXL,DYLDZ,DTF)
REYNO=1.25E4;CJET=1.0;HSLOT=.0125;WJET=5.;TKEIN=0.01*WJET*WJET
GMIXL=0.09*HSLOT;EPSIN=.1643*TKEIN**1.5/GMIXL
    GROUP 3-5. Grid specification
PARAB=T;NY=30;NREGY=2
IREGY=1;GRDPWR(Y,20,0.5*HSLOT,1.0)
IREGY=2;GRDPWR(Y,10,0.5*HSLOT,1.0)
  ** Linear Grid Expansion
IF(CARTES) THEN
+ DYLDZ=0.112*2.5;NZ=120;DZW1=0.1;DTF=0.008
ELSE
+ DYLDZ=0.12*2.5;NZ=150;DZW1=0.07;DTF=0.004
ENDIF
AZYV=1.0;ZWADD=YVLAST/DYLDZ
AZDZ=PROPY;IPARAB=1
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,SC1);TURMOD(REYSTRS,DTF)
    GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.0
    GROUP 9. Properties of the medium (or media)
ENUL=WJET*HSLOT/REYNO
    GROUP 11. Initialization of variable or porosity fields
FIINIT(KE)=TKEIN;FIINIT(EP)=EPSIN
FIINIT(U2RS)=2.*TKEIN/3.
FIINIT(V2RS)=FIINIT(U2RS);FIINIT(W2RS)=FIINIT(U2RS)
FIINIT(VWRS)=0.3*TKEIN;FIINIT(SC1)=CJET
    GROUP 13. Boundary conditions and special sources
    1. Outer Boundary -- free stream
PATCH(HIGHY,NORTH,#1,#1,#2,#2,1,NZ,#1,#1)
COVAL(HIGHY,P1,1.0E4,0.0);COVAL(HIGHY,SC1,ONLYMS,0.0)
COVAL(HIGHY,W1,ONLYMS,0.0);COVAL(HIGHY,V1,ONLYMS,0.0)
    2. Inlet Boundary-- uniform flow
INLET(UNIFORM,LOW,#1,#1,#1,#1,#1,#1,#1,#1)
VALUE(UNIFORM,P1,WJET);VALUE(UNIFORM,W1,WJET)
VALUE(UNIFORM,SC1,CJET)
VALUE(UNIFORM,KE,TKEIN);VALUE(UNIFORM,EP,EPSIN)
VALUE(UNIFORM,W2RS,2.*TKEIN/3.);VALUE(UNIFORM,V2RS,2.*TKEIN/3.)
VALUE(UNIFORM,U2RS,2.*TKEIN/3.)
PATCH(SMPLS,SOUTH,1,1,1,1,1,NZ,1,1)
COVAL(SMPLS,VWRS,GRND1,0.0);COVAL(SMPLS,VSC1,GRND1,0.0)
    GROUP 16. Termination of iterations
LITHYD=30
    GROUP 18. Limits on variables or increments to them
VARMIN(W1)=1.E-10;VARMIN(EP)=1.E-8*RHO1*HSLOT*WJET*EPSIN
VARMIN(U2RS)=1.E-10;VARMIN(V2RS)=1.E-10;VARMIN(W2RS)=1.E-10
VARMIN(SC1)=1.E-10
    GROUP 22. Monitor print-out
IZMON=NZ/2;IYMON=NY/2;ITABL=3;NPLT=5;IPLTL=LITHYD
TSTSWP=-1;NYPRIN=1;NZPRIN=NZ
    GROUP 23. Field print-out and plot control
ORSIZ=0.4;PATCH(IZEQNZ,PROFIL,1,1,1,NY,NZ,NZ,1,1)
PLOT(IZEQNZ,W1,0.0,0.0)
    GROUP 24. Dumps for restarts
RESREF(P1)=1.E-8*HSLOT*WJET; RESREF(W1)=1.E-8*RHO1*HSLOT*WJET*WJET
RESREF(SC1)=1.E-8*RHO1*HSLOT*CJET*WJET; RESREF(V1)=RESREF(W1)
 
IF(IRSMSM.EQ.1) THEN
+ RELAX(VSC1,LINRLX,0.1)
ENDIF
RG(1)=HSLOT;LG(1)=T;IG(1)=50