photon use
   p;parphi
   5 1 1
 
   view y;   gr ou y 1
   con r1 y 1 sh;0 1 50
   msg heavy-phase density = 1000.0
   msg lighter-phase concentrations
   msg horizontal coordinate is time, increasing to the right
   pause;con off;red;con r1 y 3 sh;0 1 50
   msg heavy-phase density = 250.0
   msg lighter-phase concentrations
   msg horizontal coordinate is time, increasing to the right
   pause;con off;red;con r1 y 5 sh;0 1 50
   msg heavy-phase density = 50.0
   msg lighter-phase concentrations
   msg horizontal coordinate is time, increasing to the right
   pause
   ext;phi;;;
 
   view -z;up x
   con r1 z 1 fi;0.001;gr z 1
   msg The lighter-fluid volume fraction at the last time step
   msg RHO2 = 1000. on the left and 50. on the right
   enduse
 
    GROUP 1. Run title and other preliminaries
TEXT(1-D SEDIMENTATION; parametric study:W773
TITLE
  DISPLAY
 
  The continuous phase has density =1.0. The influence of the
  second-phase density is demonstrated by making the following
  settings:
         IY    1       2     3     4     5
         RHO2  1000.0  500.0 250.0 100.0 50.0
 
  The 2D flow is converted to five independent 1D ones by fixing
  the y-direction velocities to zero.
 
  This device of using a "spare" dimension for showing the influence
  of a data-input parameter often saves time.
 
  The heavy-fluid density is made a function of y by initial-value
  settings of H2, with the option RHO2=LINSCAL (GRND1), which makes
  the second phase density a linear function of H2.
 
  Time-direction plots are made possible by setting IDISPA = 1.
 
 
  ENDDIS
  END
    GROUP 2. Transience; time-step specification
STEADY=F;GRDPWR(T,10,10.0,1.0)
 
    GROUP 3. X-direction grid specification
GRDPWR(X,10,1.0,1.0)
    GROUP 4. Y-direction grid specification
GRDPWR(Y,5,1.0,1.0)
    GROUP 7. Variables stored, solved & named
ONEPHS=F
SOLVE(P1,U1,U2,V1,V2,R1,R2);NAME(U1)=1U;NAME(U2)=2U
STORE(H2);NAME(H2)=DEN2
    GROUP 8
  ** diffusion terms cut out entirely
TERMS(1U,Y,Y,N,P,P,P);TERMS(2U,Y,Y,N,P,P,P)
TERMS(V1,Y,Y,N,P,P,P);TERMS(V2,Y,Y,N,P,P,P)
TERMS(R1,Y,Y,N,P,P,P);TERMS(R2,Y,Y,N,P,P,P)
 
    GROUP 9. Properties of the medium (or media)
  ** the following line mahes DEN2 = H2
RHO2=LINSCAL;RHO2A=0.0;RHO2B=1.0
 
    GROUP 10. Inter-phase-transfer processes and properties
CFIPS=5.E4
    GROUP 11. Initialization of variable or porosity fields
FIINIT(R1)=0.5;FIINIT(R2)=0.5;FIINIT(DEN2)=1000.0
INIADD=F
PATCH(IYEQ2,INIVAL,1,NX,2,2,1,1,1,1);COVAL(IYEQ2,DEN2,0.0,500.0)
PATCH(IYEQ3,INIVAL,1,NX,3,3,1,1,1,1);COVAL(IYEQ3,DEN2,0.0,250.0)
PATCH(IYEQ4,INIVAL,1,NX,4,4,1,1,1,1);COVAL(IYEQ4,DEN2,0.0,100.0)
PATCH(IYEQ5,INIVAL,1,NX,5,5,1,1,1,1);COVAL(IYEQ5,DEN2,0.0, 50.0)
 
    GROUP 13. Boundary conditions and special sources
PATCH(GRAVITY,PHASEM,1,NX,1,NY,1,1,1,LSTEP)
COVAL(GRAVITY,1U,FIXFLU,-9.81);COVAL(GRAVITY,2U,FIXFLU,-9.81)
 
PATCH(FREEZEV,CELL,1,NX,1,NY,1,1,1,LSTEP)
COVAL(FREEZEV,V1,FIXVAL,0.0)
COVAL(FREEZEV,V2,FIXVAL,0.0)
 
PATCH(TOP,CELL,NX,NX,1,NY,1,1,1,LSTEP);COVAL(TOP,P1,1.0,0.0)
 
    GROUP 15. Termination of sweeps
LSWEEP=30
RESREF(P1)=1.E-6;RESREF(R1)=1.E-6;RESREF(R2)=1.E-6
RESREF(1U)=1.e-6;RESREF(2U)=1.E-6
    GROUP 17. Under-relaxation devices
RELAX(R2,LINRLX,0.5);RELAX(R1,LINRLX,0.5)
RELAX(1U,FALSDT,0.1);RELAX(2U,FALSDT,0.1)
SPEDAT(SET,GXMONI,TRANSIENT,L,F)
    GROUP 21. Print-out of variables
OUTPUT(R1,N,N,N,N,N,N)
OUTPUT(P1,Y,Y,Y,Y,Y,Y);OUTPUT(R2,Y,Y,Y,Y,Y,Y)
OUTPUT(1U,Y,Y,Y,Y,Y,Y);OUTPUT(2U,Y,Y,Y,Y,Y,Y)
    GROUP 22. Spot-value print-out
NTPRIN=5;IXMON=2;UWATCH=T;TSTSWP=LSWEEP-1
    GROUP 23. Field print-out and plot control
IPLTF=2;IPLTL=LSWEEP;XZPR=T;ITABL=1;IDISPA=1
    GROUP 24. Dumps for restarts